# Event /plot done
# Event /plot continue

# Staff-Mode

# Accept (Anuller/Ok)
# Deny (Anuller/Giv også en grund)
# Plot Info (Level(Kunster,Skaber) / Ejer / Medlemmer)
# Report Info (Kopieret)
# To davy jones locker (Anuller/Ok)

# Grunde til Deny:
# Anuller
# 

PlotRankUp_Events:
    type: world
    events:
        # on plotsquared player enters plotsquaredplot:
        # - announce "<player.name||null> <context.plot>"

        # on plotsquared player leaves plotsquaredplot:
        # - announce "<player.name||null> <context.plot>"

        on p command:
        - inject PlotRankUp_Command_Task

        on plotme command:
        - inject PlotRankUp_Command_Task

        on plot command:
        - inject PlotRankUp_Command_Task

        on player right clicks with PlotRankUp_Menu_Accept:
        - determine cancelled passively
        - run PlotRankUp_AskForConfirm_Task instantly context:accept

        on player right clicks with PlotRankUp_Menu_Deny:
        - determine cancelled passively
        - flag server PlotRankUp_Type:Deny
        - inventory set d:<player.inventory> o:in@PlotRankUp_Player_Inventory_DenyReason

        on player right clicks with PlotRankUp_Menu_Info:
        - determine cancelled passively
        - execute as_player "plot info"

        on player right clicks with PlotRankUp_Menu_Reports:
        - determine cancelled passively
        - execute as_player "plot reports"

        on player right clicks with PlotRankUp_Menu_Trash:
        - determine cancelled passively
        - run PlotRankUp_AskForConfirm_Task instantly context:trash

        on player right clicks with PlotRankUp_Menu_Confirm:
        - determine cancelled passively
        - define plot <player.flag[PlotRankUp_Plot_Target]>
        - define type <player.flag[PlotRankUp_Type]>
        - flag server PlotRankUp_Queue:<-:<def[plot]>
        - if <def[type]> == accept {
            - define rank <player.flag[PlotRankUp_Plot_RankTo]>
            - foreach <def[plot].as_plotsquared_plot.owners> {
                - run PlotRankup_Accepted_Task instantly player:<def[value]> context:<def[rank]>
            }
        }
        else if <def[type]> == trash {
            - execute as_player "plot clear"
        }
        - wait 10t
        - run PlotRankUp_NextPlot_Task instantly

        on player right clicks with PlotRankUp_Menu_Cancel:
        - determine cancelled passively
        - flag player PlotRankup_PlotDeny_Other:!
        - flag server PlotRankUp_Plot_Target:<player.flag[PlotRankUp_Plot_Target]>
        - inventory set d:<player.inventory> o:in@PlotRankUp_Player_Inventory

        on player right clicks with PlotRankUp_Menu_DenyReason_item1:
        - inject PlotRankUp_DenyReason_Task
        on player right clicks with PlotRankUp_Menu_DenyReason_item2:
        - inject PlotRankUp_DenyReason_Task
        on player right clicks with PlotRankUp_Menu_DenyReason_item3:
        - inject PlotRankUp_DenyReason_Task
        on player right clicks with PlotRankUp_Menu_DenyReason_item4:
        - inject PlotRankUp_DenyReason_Task
        on player right clicks with PlotRankUp_Menu_DenyReason_item5:
        - inject PlotRankUp_DenyReason_Task
        on player right clicks with PlotRankUp_Menu_DenyReason_item6:
        - inject PlotRankUp_DenyReason_Task
        on player right clicks with PlotRankUp_Menu_DenyReason_item7:
        - inject PlotRankUp_DenyReason_Task
        on player right clicks with PlotRankUp_Menu_DenyReason_Other:
        - inject PlotRankUp_DenyReason_Task

PlotRankUp_DenyReason_Task:
    type: task
    script:
    - determine cancelled passively
    - define title <context.item.display_name.strip_color||null>
    # - if <context.item.scriptname||null> == "CTF_LobbyMenu_Menu_Wall" {
        # - queue clear
    # }
    - if <def[title].starts_with[Andet]||false> {
        - narrate "<&a>Skriv din egen kommentar med <&b>/grund (text)"
        - flag player PlotRankup_PlotDeny_Other
    }
    else {
        - define plot <player.flag[PlotRankUp_Plot_Target]>
        - flag server PlotRankUp_Queue:<-:<def[plot]>
        - flag player PlotRankup_PlotDeny_Other:!
        - execute as_player "plot comment owner Plot afvist grund<&co> <def[title]>"
        - define owners <def[plot].as_plotsquared_plot.owners.filter[is_online]||li@>
        - if <def[owners].is_empty.not||false> {
            - narrate format:util_ff "<&7>Dit plot blev afvist. Mere info <&e>/plot inbox"
            - title "title:<&c>Plot Afvist" "subtitle:<&7>Mere info <&e>/plot inbox" targets:<def[owners]>
            - foreach <def[owners]> {
                - run PlotRankup_Cooldown_Give instantly player:<def[value]>
            }
        }
        - run PlotRankUp_NextPlot_Task instantly
    }

PlotRankup_Cooldown_Give:
    type: task
    script:
    - flag player PlotRankup_Done_Cooldown duration:2d

PlotRankup_PlotDeny_Other_Command:
    type: command
    name: grund
    description: PlotDeny Other Command
    usage: /grund
    aliases:
    - grun
    - reason
    - grud
    script:
    - if <player.is_op.not||true> {
        - queue clear
    }
    - if <player.has_flag[PlotRankup_PlotDeny_Other].not> {
        - narrate format:util_ff "<&c>Andet grund er ikke angivet."
        - queue clear
    }
    - define plot <player.flag[PlotRankUp_Plot_Target]>
    - flag server PlotRankUp_Queue:<-:<def[plot]>
    - flag player PlotRankup_PlotDeny_Other:!
    - define owners <def[plot].as_plotsquared_plot.owners.filter[is_online]||li@>
    - if <def[owners].is_empty> {
        - narrate format:util_ff "<&7>Dit plot blev afvist. Mere info <&a>/plot inbox"
        - title "title:<&c>Plot Afvist" "subtitle:<&7>Mere info <&a>/plot inbox" targets:<def[owners]>
    }
    - execute as_player "plot comment owner Plot afvist grund<&co> <context.raw_args>"
    - run PlotRankUp_NextPlot_Task instantly

PlotRankup_Accepted_Task:
    type: task
    definitions: rank
    script:
    - announce format:util_ff "<&6><player.name> <&a>fik godkendt sit plot og er nu <&l><&6><def[rank]>"
    - if <player.groups.contains[VIP]||false> {
        - execute as_server "manuadd <player.name> <def[rank]>"
        - execute as_server "manuaddsub <player.name> VIP"
    }
    else {
        - execute as_server "manuadd <player.name> <def[rank]>"
    }

PlotRankUp_Command_Task:
    type: task
    script:
    - if <context.args.get[1]||null> == done {
        - determine cancelled passively
        - inject Plot_Done_Task
    }
    else if <context.args.get[1]||null> == continue {
        - determine cancelled passively
        - inject Plot_Continue_Task
    }
    else if <context.args.get[1]||null> == approve {
        - determine cancelled passively
        - if <player.is_op.not||true> {
            - queue clear
        }
        - run PlotRankUp_Mode_Task instantly player:<player>
    }

PlotRankup_Done:
    type: command
    name: done
    description: Finishes a plot
    usage: /done
    aliases:
    - finish
    - færdig
    script:
    - inject Plot_Done_Task

PlotRankup_Continue:
    type: command
    name: continue
    description: Continues a plot
    usage: /continue
    aliases:
    - fortsæt
    script:
    - inject Plot_Continue_Task

Plot_Continue_Task:
    type: task
    script:
    - define plot <player.location.plotsquared_plot||null>
    - if <def[plot]> == null {
        - narrate format:util_ff "<&c>Du er ikke på noget plot!"
        - queue clear
    }
    - if <def[plot].owners.contains[<player>].not||true> {
        - narrate format:util_ff "<&c>Du er ikke ejeren af dette plot!"
        - queue clear
    }
    - define Queues <server.flag[PlotRankUp_Queue].as_list||li@>
    - if <def[Queues].contains[<def[plot]>].not||true> {
        - narrate format:util_ff "<&c>Dit plot er ikke markeret færdigt."
        - queue clear
    }
    - flag server PlotRankUp_Queue:<-:<def[plot]>
    - narrate format:util_ff "<&7>Dit plot er ikke længere markeret færdigt..."

Plot_Done_Task:
    type: task
    script:
    - if <player.has_flag[PlotRankup_Done_Cooldown]> {
        - narrate format:util_ff "<&c>Du kan først prøve igen om <player.flag[PlotRankup_Done_Cooldown].expiration.formatted||0>"
        - narrate format:util_ff "<&7>Husk at checke hvorfor den blev afvist <&e>/plot inbox"
        - queue clear
    }
    - define plot <player.location.plotsquared_plot||null>
    - if <def[plot]> == null {
        - narrate format:util_ff "<&c>Du er ikke på noget plot!"
        - queue clear
    }
    - if <def[plot].owners.contains[<player>].not||true> {
        - narrate format:util_ff "<&c>Du er ikke ejeren af dette plot!"
        - queue clear
    }
    - define Queues <server.flag[PlotRankUp_Queue].as_list||li@>
    - if <def[Queues].as_list.contains[<def[plot]>]||false> {
        - narrate format:util_ff "<&7>Dit plot er allerede markeret færdig."
    }
    else {
        - flag server PlotRankUp_Queue:->:<def[plot]>
        - narrate format:util_ff "<&7>Dit plot er markeret færdigt."
    }
    - narrate format:util_ff "<&7>Hvis du føler den ikke er færdig endnu, kan du skrive <&a>/continue"
    - narrate format:util_ff "<&7>Husk at checke <&a>/rank <&7>for mere info"

PlotRankUp_NextPlot_Task:
    type: task
    script:
    - define plots_done <server.flag[PlotRankUp_Queue].as_list||li@>
    - if <def[plots_done].is_empty> {
        - narrate "<&7>Der er flere plots at checke..."
        - run PlotRankUp_Mode_Task instantly player:<player>
        - queue clear
    }
    - define plot <def[plots_done].get[1].as_plotsquared_plot||null>
    - if <def[plot]> == null {
        - announce to_ops "<&d>Der opstod en fejl i at checke <def[plots_done].get[1]>"
        - queue clear
    }
    - if <def[plot].as_element.contains[arkitekt]> {
        - define rank "<&2>Bygger"
    }
    else if <def[plot].as_element.contains[skaber]> {
        - define rank "<&6>Arkitekt"
    }
    else if <def[plot].as_element.contains[kunstner]> {
        - define rank "<&e>Skaber"
    }
    else {
        - define rank "<&b>Kunstner"
    }
    - narrate "<&7>"
    - narrate format:util_ff "<&7>Teleporteret til næste plot."
    - narrate format:util_ff "<&7>Dette plot skal vurderes til <def[rank]>"
    - narrate "<&7>"
    - flag player PlotRankUp_Plot_RankTo:<def[rank].strip_color>
    - flag player PlotRankUp_Plot_Target:<def[plot]>
    - flag server PlotRankUp_Plot_Target:<def[plot].as_element.after[@]>
    - inventory set d:<player.inventory> o:in@PlotRankUp_Player_Inventory
    - teleport <player> <def[plot].home>

PlotRankUp_Player_Inventory:
  type: inventory
  inventory: PLAYER
  definitions:
    Accept: PlotRankUp_Menu_Accept
    Deny: PlotRankUp_Menu_Deny
    Info: PlotRankUp_Menu_Info
    Reports: PlotRankUp_Menu_Reports
    Trash: PlotRankUp_Menu_Trash
  slots:
    - "[Accept] [] [Deny] [] [Info] [] [Reports] [] [Trash]"
    - "[] [] [] [] [] [] [] [] []"
    - "[] [] [] [] [] [] [] [] []"
    - "[] [] [] [] [] [] [] [] []"
PlotRankUp_Player_Inventory_Confirm:
  type: inventory
  inventory: PLAYER
  definitions:
    Confirm: PlotRankUp_Menu_Confirm
    Cancel: PlotRankUp_Menu_Cancel
  slots:
    - "[] [Confirm] [] [] [] [] [] [Cancel] []"
    - "[] [] [] [] [] [] [] [] []"
    - "[] [] [] [] [] [] [] [] []"
    - "[] [] [] [] [] [] [] [] []"

PlotRankUp_Menu_Accept:
    type: item
    material: GREEN_RECORD
    display name: <&a><&l>Accept
    lore:
    - <&3>Godkender plottet

PlotRankUp_Menu_Deny:
    type: item
    material: RECORD_4
    display name: <&c><&l>Reject
    lore:
    - <&3>Afviser plottet

PlotRankUp_Menu_Info:
    type: item
    material: NETHER_STAR
    display name: <&b><&l>Info (Medlemmer<&co> <server.flag[PlotRankUp_Plot_Target].as_plotsquared_plot.owners.include[<server.flag[PlotRankUp_Plot_Target].as_plotsquared_plot.members>].include[<server.flag[PlotRankUp_Plot_Target].as_plotsquared_plot.trusted>].deduplicate.size>)
    lore:
    - <&3>Ejere<&co>
    - <&b><server.flag[PlotRankUp_Plot_Target].as_plotsquared_plot.owners.parse[name].space_separated||<&sp>>
    - <&7>
    - <&3>Trusted<&co>
    - <&b><server.flag[PlotRankUp_Plot_Target].as_plotsquared_plot.trusted.parse[name].space_separated||<&sp>>
    - <&7>
    - <&3>Members<&co>
    - <&b><server.flag[PlotRankUp_Plot_Target].as_plotsquared_plot.members.parse[name].space_separated||<&sp>>

PlotRankUp_Menu_Reports:
    type: item
    material: EMERALD
    display name: <&e><&l>Reports (<server.flag[Plots.<server.flag[PlotRankUp_Plot_Target]>.Reports]||0>)
    lore:
    - <&3><server.flag[Plots.<server.flag[PlotRankUp_Plot_Target]>.Reports]||0> har reporteret dette plot.
    - <&3>Mere info check /plot reports

PlotRankUp_Menu_Trash:
    type: item
    material: COAL
    display name: <&d><&l>Trash
    lore:
    - <&3>Skal plottet clears?

PlotRankUp_Menu_Confirm:
    type: item
    material: WOOL,5
    display name: <&a><&l>CONFIRM <&a>(<server.flag[PlotRankUp_Type]>)
    lore:
    - <&3>Godkend

PlotRankUp_Menu_Cancel:
    type: item
    material: WOOL,14
    display name: <&c><&l>CANCEL <&c>(<server.flag[PlotRankUp_Type]>)
    lore:
    - <&3>Anuller

PlotRankUp_Player_Inventory_DenyReason:
  type: inventory
  inventory: PLAYER
  definitions:
    Item1: PlotRankUp_Menu_DenyReason_item1
    Item2: PlotRankUp_Menu_DenyReason_item2
    Item3: PlotRankUp_Menu_DenyReason_item3
    Item4: PlotRankUp_Menu_DenyReason_item4
    Item5: PlotRankUp_Menu_DenyReason_item5
    Item6: PlotRankUp_Menu_DenyReason_item6
    Other: PlotRankUp_Menu_DenyReason_Other
    Cancel: PlotRankUp_Menu_Cancel
  slots:
    - "[Item1] [Item2] [Item3] [Item4] [Item5] [Item6] [Other] [] [Cancel]"
    - "[] [] [] [] [] [] [] [] []"
    - "[] [] [] [] [] [] [] [] []"
    - "[] [] [] [] [] [] [] [] []"

PlotRankUp_Menu_DenyReason_item1:
    type: item
    material: STONE
    display name: <&e>Plottet er for tomt/flat
    lore:
    - <&3>Vælg grund

PlotRankUp_Menu_DenyReason_item2:
    type: item
    material: STONE,1
    display name: <&e>Flere Bygninger mangler
    lore:
    - <&3>Vælg grund

PlotRankUp_Menu_DenyReason_item3:
    type: item
    material: STONE,2
    display name: <&e>Bygningerne er kedelige
    lore:
    - <&3>Vælg grund

PlotRankUp_Menu_DenyReason_item4:
    type: item
    material: STONE,3
    display name: <&e>Det er useriøst
    lore:
    - <&3>Vælg grund

PlotRankUp_Menu_DenyReason_item5:
    type: item
    material: STONE,4
    display name: <&e>Der er intet tema
    lore:
    - <&3>Vælg grund

PlotRankUp_Menu_DenyReason_item6:
    type: item
    material: STONE,5
    display name: <&e>Det rodet, man kan ikke se en sammenhæng
    lore:
    - <&3>Vælg grund

PlotRankUp_Menu_DenyReason_Other:
    type: item
    material: STONE,6
    display name: <&6>Andet (Skriv selv)
    lore:
    - <&3>Vælg hvis andre ikke passer

PlotRankUp_AskForConfirm_Task:
    type: task
    definitions: type
    script:
    - flag player PlotRankUp_Type:<def[type]>
    - flag server PlotRankUp_Type:<def[type]>
    - inventory set d:<player.inventory> o:in@PlotRankUp_Player_Inventory_Confirm

PlotRankUp_Mode_Task:
    type: task
    script:
    - if <player.has_flag[PlotRankUp_Mode]> {
        - flag player PlotRankUp_Mode:!
        - inventory set d:<player.inventory> o:in@<player.uuid>_inv
        - note remove as:<player.uuid>_inv
        - teleport <player> <player.flag[Plotrankup_Last_pos]>
        - flag player Plotrankup_Last_pos:!
        - narrate "<&b>Plot-Rankup Mode slået <&c>fra"
    }
    else {
        - define plots_done <server.flag[PlotRankUp_Queue].as_list||li@>
        - if <def[plots_done].is_empty> {
            - narrate "<&7>Der er ingen plots at checke..."
            - queue clear
        }
        - flag player PlotRankUp_Mode
        - flag player Plotrankup_Last_pos:<player.location>
        - note "<player.inventory>" as:<player.uuid>_inv
        - run PlotRankUp_NextPlot_Task instantly player:<player>
    }